7. Instructions composées
*************************

Les instructions composées contiennent d’autres (groupes d’)
instructions ; elles affectent ou contrôlent l’exécution de ces autres
instructions d’une manière ou d’une autre. En général, une instruction
composée couvre plusieurs lignes bien que, dans sa forme la plus
simple, une instruction composée peut tenir sur une seule ligne.

The "if", "while" and "for" statements implement traditional control
flow constructs.  "try" specifies exception handlers and/or cleanup
code for a group of statements.  Function and class definitions are
also syntactically compound statements.

Compound statements consist of one or more “clauses.”  A clause
consists of a header and a “suite.”  The clause headers of a
particular compound statement are all at the same indentation level.
Each clause header begins with a uniquely identifying keyword and ends
with a colon.  A suite is a group of statements controlled by a
clause.  A suite can be one or more semicolon-separated simple
statements on the same line as the header, following the header’s
colon, or it can be one or more indented statements on subsequent
lines.  Only the latter form of suite can contain nested compound
statements; the following is illegal, mostly because it wouldn’t be
clear to which "if" clause a following "else" clause would belong:

   if test1: if test2: print x

Also note that the semicolon binds tighter than the colon in this
context, so that in the following example, either all or none of the
"print" statements are executed:

   if x < y < z: print x; print y; print z

En résumé :

   compound_stmt ::= if_stmt
                     | while_stmt
                     | for_stmt
                     | try_stmt
                     | with_stmt
                     | funcdef
                     | classdef
                     | decorated
   suite         ::= stmt_list NEWLINE | NEWLINE INDENT statement+ DEDENT
   statement     ::= stmt_list NEWLINE | compound_stmt
   stmt_list     ::= simple_stmt (";" simple_stmt)* [";"]

Note that statements always end in a "NEWLINE" possibly followed by a
"DEDENT". Also note that optional continuation clauses always begin
with a keyword that cannot start a statement, thus there are no
ambiguities (the “dangling "else"” problem is solved in Python by
requiring nested "if" statements to be indented).

L’agencement des règles de grammaire dans les sections qui suivent
place chaque clause sur une ligne séparée pour plus de clarté.


7.1. L’instruction "if"
=======================

L’instruction "if" est utilisée pour exécuter des instructions en
fonction d’une condition :

   if_stmt ::= "if" expression ":" suite
               ( "elif" expression ":" suite )*
               ["else" ":" suite]

Elle sélectionne exactement une des suites en évaluant les expressions
une par une jusqu’à ce qu’une soit vraie (voir la section Opérations
booléennes pour la définition de vrai et faux) ; ensuite cette suite
est exécutée (et aucune autre partie de l’instruction "if" n’est
exécutée ou évaluée). Si toutes les expressions sont fausses, la suite
de la clause "else", si elle existe, est exécutée.


7.2. L’instruction "while"
==========================

L’instruction "while" est utilisée pour exécuter des instructions de
manière répétée tant qu’une expression est vraie :

   while_stmt ::= "while" expression ":" suite
                  ["else" ":" suite]

Python évalue l’expression de manière répétée et, tant qu’elle est
vraie, exécute la première suite ; si l’expression est fausse (ce qui
peut arriver même lors du premier test), la suite de la clause "else",
si elle existe, est exécutée et la boucle se termine.

Une instruction "break" exécutée dans la première suite termine la
boucle sans exécuter la suite de la clause "else". Une instruction
"continue" exécutée dans la première suite saute le reste de la suite
et retourne au test de l’expression.


7.3. L’instruction "for"
========================

L’instruction "for" est utilisée pour itérer sur les éléments d’une
séquence (par exemple une chaîne, un tuple ou une liste) ou un autre
objet itérable :

   for_stmt ::= "for" target_list "in" expression_list ":" suite
                ["else" ":" suite]

The expression list is evaluated once; it should yield an iterable
object.  An iterator is created for the result of the
"expression_list".  The suite is then executed once for each item
provided by the iterator, in the order of ascending indices.  Each
item in turn is assigned to the target list using the standard rules
for assignments, and then the suite is executed.  When the items are
exhausted (which is immediately when the sequence is empty), the suite
in the "else" clause, if present, is executed, and the loop
terminates.

A "break" statement executed in the first suite terminates the loop
without executing the "else" clause’s suite.  A "continue" statement
executed in the first suite skips the rest of the suite and continues
with the next item, or with the "else" clause if there was no next
item.

The suite may assign to the variable(s) in the target list; this does
not affect the next item assigned to it.

The target list is not deleted when the loop is finished, but if the
sequence is empty, it will not have been assigned to at all by the
loop.  Hint: the built-in function "range()" returns a sequence of
integers suitable to emulate the effect of Pascal’s "for i := a to b
do"; e.g., "range(3)" returns the list "[0, 1, 2]".

Note: There is a subtlety when the sequence is being modified by the
  loop (this can only occur for mutable sequences, e.g. lists). An
  internal counter is used to keep track of which item is used next,
  and this is incremented on each iteration.  When this counter has
  reached the length of the sequence the loop terminates.  This means
  that if the suite deletes the current (or a previous) item from the
  sequence, the next item will be skipped (since it gets the index of
  the current item which has already been treated).  Likewise, if the
  suite inserts an item in the sequence before the current item, the
  current item will be treated again the next time through the loop.
  This can lead to nasty bugs that can be avoided by making a
  temporary copy using a slice of the whole sequence, e.g.,

     for x in a[:]:
         if x < 0: a.remove(x)


7.4. L’instruction "try"
========================

L’instruction "try" spécifie les gestionnaires d’exception ou le code
de nettoyage pour un groupe d’instructions :

   try_stmt  ::= try1_stmt | try2_stmt
   try1_stmt ::= "try" ":" suite
                 ("except" [expression [("as" | ",") identifier]] ":" suite)+
                 ["else" ":" suite]
                 ["finally" ":" suite]
   try2_stmt ::= "try" ":" suite
                 "finally" ":" suite

Modifié dans la version 2.5: In previous versions of Python,
"try"…"except"…"finally" did not work. "try"…"except" had to be nested
in "try"…"finally".

The "except" clause(s) specify one or more exception handlers. When no
exception occurs in the "try" clause, no exception handler is
executed. When an exception occurs in the "try" suite, a search for an
exception handler is started.  This search inspects the except clauses
in turn until one is found that matches the exception.  An expression-
less except clause, if present, must be last; it matches any
exception.  For an except clause with an expression, that expression
is evaluated, and the clause matches the exception if the resulting
object is « compatible » with the exception.  An object is compatible
with an exception if it is the class or a base class of the exception
object, or a tuple containing an item compatible with the exception.

Si aucune clause "except" ne correspond à l’exception, la recherche
d’un gestionnaire d’exception se poursuit dans le code englobant et
dans la pile d’appels [1].

Si l’évaluation d’une expression dans l’en-tête d’une clause "except"
lève une exception, la recherche initiale d’un gestionnaire est
annulée et une recherche commence pour la nouvelle exception dans le
code englobant et dans la pile d’appels (c’est traité comme si
l’instruction "try" avait levé l’exception).

When a matching except clause is found, the exception is assigned to
the target specified in that except clause, if present, and the except
clause’s suite is executed.  All except clauses must have an
executable block.  When the end of this block is reached, execution
continues normally after the entire try statement.  (This means that
if two nested handlers exist for the same exception, and the exception
occurs in the try clause of the inner handler, the outer handler will
not handle the exception.)

Before an except clause’s suite is executed, details about the
exception are assigned to three variables in the "sys" module:
"sys.exc_type" receives the object identifying the exception;
"sys.exc_value" receives the exception’s parameter;
"sys.exc_traceback" receives a traceback object (see section
Hiérarchie des types standards) identifying the point in the program
where the exception occurred. These details are also available through
the "sys.exc_info()" function, which returns a tuple "(exc_type,
exc_value, exc_traceback)".  Use of the corresponding variables is
deprecated in favor of this function, since their use is unsafe in a
threaded program.  As of Python 1.5, the variables are restored to
their previous values (before the call) when returning from a function
that handled an exception.

The optional "else" clause is executed if the control flow leaves the
"try" suite, no exception was raised, and no "return", "continue", or
"break" statement was executed.  Exceptions in the "else" clause are
not handled by the preceding "except" clauses.

If "finally" is present, it specifies a “cleanup” handler.  The "try"
clause is executed, including any "except" and "else" clauses.  If an
exception occurs in any of the clauses and is not handled, the
exception is temporarily saved. The "finally" clause is executed.  If
there is a saved exception, it is re-raised at the end of the
"finally" clause. If the "finally" clause raises another exception or
executes a "return" or "break" statement, the saved exception is
discarded:

   >>> def f():
   ...     try:
   ...         1/0
   ...     finally:
   ...         return 42
   ...
   >>> f()
   42

L’information relative à l’exception n’est pas disponible pour le
programme pendant l’exécution de la clause "finally".

Lorsqu’une instruction "return", "break" ou "continue" est exécutée
dans la suite d’une instruction "try" d’une construction
"try"…"finally", la clause "finally" est aussi exécutée à la sortie.
Une instruction "continue" est illégale dans une clause "finally" (la
raison est que l’implémentation actuelle pose problème — il est
possible que cette restriction soit levée dans le futur).

La valeur de retour d’une fonction est déterminée par la dernière
instruction "return" exécutée.  Puisque la clause "finally" s’exécute
toujours, une instruction "return" exécutée dans le "finally" sera
toujours la dernière clause exécutée :

   >>> def foo():
   ...     try:
   ...         return 'try'
   ...     finally:
   ...         return 'finally'
   ...
   >>> foo()
   'finally'

Vous trouvez des informations supplémentaires relatives aux exceptions
dans la section Exceptions et, dans la section L’instruction raise,
des informations relatives à l’utilisation de l’instruction "raise"
pour produire des exceptions.


7.5. L’instruction "with"
=========================

Nouveau dans la version 2.5.

L’instruction "with" est utilisée pour encapsuler l’exécution d’un
bloc avec des méthodes définies par un gestionnaire de contexte (voir
la section Gestionnaire de contexte With). Cela permet d’utiliser de
manière simple le patron de conception classique
"try"…."except"…"finally".

   with_stmt ::= "with" with_item ("," with_item)* ":" suite
   with_item ::= expression ["as" target]

L’exécution de l’instruction "with" avec un seul « élément » (*item*
dans la grammaire) se déroule comme suit :

1. L’expression de contexte (l’expression donnée dans le
   "with_item") est évaluée pour obtenir un gestionnaire de contexte.

2. La méthode "__exit__()" du gestionnaire de contexte est chargée
   pour une utilisation ultérieure.

3. La méthode "__enter__()" du gestionnaire de contexte est
   invoquée.

4. Si une cible (*target* dans la grammaire ci-dessus) a été
   incluse dans l’instruction "with", la valeur de retour de
   "__enter__()" lui est assignée.

   Note: L’instruction "with" garantit que si la méthode
     "__enter__()" se termine sans erreur, alors la méthode
     "__exit__()" est toujours appelée. Ainsi, si une erreur se
     produit pendant l’assignation à la liste cible, elle est traitée
     de la même façon qu’une erreur se produisant dans la suite. Voir
     l’étape 6 ci-dessous.

5. La suite est exécutée.

6. The context manager’s "__exit__()" method is invoked. If an
   exception caused the suite to be exited, its type, value, and
   traceback are passed as arguments to "__exit__()". Otherwise, three
   "None" arguments are supplied.

   If the suite was exited due to an exception, and the return value
   from the "__exit__()" method was false, the exception is reraised.
   If the return value was true, the exception is suppressed, and
   execution continues with the statement following the "with"
   statement.

   Si l’on est sorti de la suite pour une raison autre qu’une
   exception, la valeur de retour de "__exit__()" est ignorée et
   l’exécution se poursuit à l’endroit normal pour le type de sortie
   prise.

Avec plus d’un élément, les gestionnaires de contexte sont traités
comme si plusieurs instructions "with" étaient imbriquées :

   with A() as a, B() as b:
       suite

est équivalente à :

   with A() as a:
       with B() as b:
           suite

Note: In Python 2.5, the "with" statement is only allowed when the
  "with_statement" feature has been enabled.  It is always enabled in
  Python 2.6.

Modifié dans la version 2.7: Prise en charge de multiples expressions
de contexte.

Voir aussi:

  **PEP 343** - The « with » statement
     La spécification, les motivations et des exemples de
     l’instruction "with" en Python.


7.6. Définition de fonctions
============================

Une définition de fonction définit un objet fonction allogène (voir la
section Hiérarchie des types standards) :

   decorated      ::= decorators (classdef | funcdef)
   decorators     ::= decorator+
   decorator      ::= "@" dotted_name ["(" [argument_list [","]] ")"] NEWLINE
   funcdef        ::= "def" funcname "(" [parameter_list] ")" ":" suite
   dotted_name    ::= identifier ("." identifier)*
   parameter_list ::= (defparameter ",")*
                      (  "*" identifier ["," "**" identifier]
                      | "**" identifier
                      | defparameter [","] )
   defparameter   ::= parameter ["=" expression]
   sublist        ::= parameter ("," parameter)* [","]
   parameter      ::= identifier | "(" sublist ")"
   funcname       ::= identifier

Une définition de fonction est une instruction qui est exécutée. Son
exécution lie le nom de la fonction, dans l’espace de noms local
courant, à un objet fonction (un objet qui encapsule le code
exécutable de la fonction).  Cet objet fonction contient une référence
à l’espace des noms globaux courant comme espace des noms globaux à
utiliser lorsque la fonction est appelée.

La définition de la fonction n’exécute pas le corps de la fonction ;
elle n’est exécutée que lorsque la fonction est appelée [2].

A function definition may be wrapped by one or more *decorator*
expressions. Decorator expressions are evaluated when the function is
defined, in the scope that contains the function definition.  The
result must be a callable, which is invoked with the function object
as the only argument. The returned value is bound to the function name
instead of the function object.  Multiple decorators are applied in
nested fashion. For example, the following code:

   @f1(arg)
   @f2
   def func(): pass

is equivalent to:

   def func(): pass
   func = f1(arg)(f2(func))

When one or more top-level *parameters* have the form *parameter* "="
*expression*, the function is said to have « default parameter values.
»  For a parameter with a default value, the corresponding *argument*
may be omitted from a call, in which case the parameter’s default
value is substituted.  If a parameter has a default value, all
following parameters must also have a default value — this is a
syntactic restriction that is not expressed by the grammar.

**Default parameter values are evaluated when the function definition
is executed.**  This means that the expression is evaluated once, when
the function is defined, and that the same « pre-computed » value is
used for each call.  This is especially important to understand when a
default parameter is a mutable object, such as a list or a dictionary:
if the function modifies the object (e.g. by appending an item to a
list), the default value is in effect modified. This is generally not
what was intended.  A way around this  is to use "None" as the
default, and explicitly test for it in the body of the function, e.g.:

   def whats_on_the_telly(penguin=None):
       if penguin is None:
           penguin = []
       penguin.append("property of the zoo")
       return penguin

Function call semantics are described in more detail in section
Appels. A function call always assigns values to all parameters
mentioned in the parameter list, either from position arguments, from
keyword arguments, or from default values.  If the form «
"*identifier" » is present, it is initialized to a tuple receiving any
excess positional parameters, defaulting to the empty tuple.  If the
form « "**identifier" » is present, it is initialized to a new
dictionary receiving any excess keyword arguments, defaulting to a new
empty dictionary.

It is also possible to create anonymous functions (functions not bound
to a name), for immediate use in expressions.  This uses lambda
expressions, described in section Expressions lambda.  Note that the
lambda expression is merely a shorthand for a simplified function
definition; a function defined in a « "def" » statement can be passed
around or assigned to another name just like a function defined by a
lambda expression.  The « "def" » form is actually more powerful since
it allows the execution of multiple statements.

**Programmer’s note:** Functions are first-class objects.  A « "def" »
form executed inside a function definition defines a local function
that can be returned or passed around.  Free variables used in the
nested function can access the local variables of the function
containing the def.  See section Noms et liaisons for details.


7.7. Définition de classes
==========================

Une définition de classe définit un objet classe (voir la section
Hiérarchie des types standards) :

   classdef    ::= "class" classname [inheritance] ":" suite
   inheritance ::= "(" [expression_list] ")"
   classname   ::= identifier

A class definition is an executable statement.  It first evaluates the
inheritance list, if present.  Each item in the inheritance list
should evaluate to a class object or class type which allows
subclassing.  The class’s suite is then executed in a new execution
frame (see section Noms et liaisons), using a newly created local
namespace and the original global namespace. (Usually, the suite
contains only function definitions.)  When the class’s suite finishes
execution, its execution frame is discarded but its local namespace is
saved. [3] A class object is then created using the inheritance list
for the base classes and the saved local namespace for the attribute
dictionary.  The class name is bound to this class object in the
original local namespace.

**Programmer’s note:** Variables defined in the class definition are
class variables; they are shared by all instances.  To create instance
variables, they can be set in a method with "self.name = value".  Both
class and instance variables are accessible through the notation «
"self.name" », and an instance variable hides a class variable with
the same name when accessed in this way. Class variables can be used
as defaults for instance variables, but using mutable values there can
lead to unexpected results.  For *new-style class*es, descriptors can
be used to create instance variables with different implementation
details.

Class definitions, like function definitions, may be wrapped by one or
more *decorator* expressions.  The evaluation rules for the decorator
expressions are the same as for functions.  The result must be a class
object, which is then bound to the class name.

-[ Notes ]-

[1] L’exception est propagée à la pile d’appels à moins qu’il n’y
    ait une clause "finally" qui lève une autre exception, ce qui
    entraîne la perte de l’ancienne exception. Cette nouvelle
    exception entraîne la perte pure et simple de l’ancienne.

[2] Une chaîne littérale apparaissant comme première instruction
    dans le corps de la fonction est transformée en attribut "__doc__"
    de la fonction et donc en *docstring* de la fonction.

[3] Une chaîne littérale apparaissant comme première instruction
    dans le corps de la classe est transformée en élément "__doc__" de
    l’espace de noms et donc en *docstring* de la classe.
